;
;
;               Embeded Window
;
;embed a custom channel window on your desktop
;
;
;***Set Popup Variable***
;
on *:connect:set %membed Embed
;
;***Make Popup in Channel Window***
;
menu channel {
  %membed:{
    %membed
  }
}
;
;***Make Popup in Enbed Window***
;
menu @embed {
  dclick:{ window -n @embed }
  Control
  .Ignore:/ignore $$1 1
  .Unignore:/ignore -r $$1 1
  .Op:/mode %embed +ooo $$1 $2 $3
  .Deop:/mode %embed -ooo $$1 $2 $3
  .Voice:/mode %embed +vvv $$1 $2 $3
  .Devoice:/mode %embed -vvv $$1 $2 $3
  .Kick:/kick %embed $$1
  -
  Clear Screen:clear
  Channel Modes:channel %embed
  Update Nicks:nklist
  -
  EXIT:{
    unembed
  }
}
;
;***Set Alias Embed***
;
alias embed {
  set %embed $chan(#)
  window -deHSl12 +dL  @embed 630 515 410 225
  window -deHSl12 +dL  @embed 630 515 410 225
  enable #embed
  set %membed Unembed
  echo 4 Window Embeded to Desktop
  nklist
}
;
;
;*** Set Alias Unembed***
;
alias unembed {
  window -c @embed
  unset %embed
  disable #embed
  set %membed Embed
}
;
;***Redirect Chat To/From the Embeded Window***
;
#embed on
;
alias nklist {
  clear -l @embed
  var %i = $nick(%embed,0)
  while (%i > 0) {
    if ($nick(%embed,%i) isop %embed) { aline -l @embed @ $+ $nick(%embed,%i) }
    elseif ($nick(%embed,%i) isvoice %embed) { aline -l @embed + $+ $nick(%embed,%i) }
    else { aline -l @embed $nick(%embed,%i) }
    dec %i 1
  }
  echo 0 @embed ***Nicklist Updated***
}
;
alias nkuw {
  timer5 1 5 nklist
  echo 8 @embed ***Nicklist Updating***
}
;
on *:input:@embed:{
  if (/* iswm $1) { echo 4 <CMD> $1- }
  else {
    msg %embed $$1-
    echo 9 < $+ $me $+ > $1-
  }
}
;
on *:text:*:%embed:{
  echo 9 @embed < $+ $nick $+ > $1-
}
;
on *:action:*:%embed:{
  echo 8 @embed < $+ $nick $+ > $1-
}
;
on *:notice:*:*:{
  echo 0 @embed < $+ $nick $+ > $1-
}
;
on *:join:%embed:{
  echo 12 @embed * $+ $nick Joins $chan
  nkuw
  echo 0 @embed *** < $+ $nick $+ > Adding to Nicklist***
}
;
on *:part:%embed:{
  echo 12 @embed * $+ $nick Departs $chan
  nkuw
}
;
on *:quit:{
  echo 12 @embed * $+ $nick has Disconnected
  nkuw
}
;
on *:op:%embed:{
  echo 8 @embed * $+ $nick OPs < $+ $$2 $3 $4 $+ > on $chan
  nkuw
}
;
on *:deop:%embed:{
  echo 8 @embed * $+ $nick DeOPs < $+ $$2 $3 $4 $+ > on $chan
  nkuw
}
;
on *:voice:%embed:{
  echo 8 @embed * $+ $nick Voices < $+ $$2 $3 $4 $+ > on $chan
  nkuw
}
;
on *:devoice:%embed:{
  echo 8 @embed * $+ $nick Devoices < $+ $$2 $3 $4 $+ > on $chan
  nkuw
}
;
on *:kick:%embed:{
  echo 4 @embed *** $+ $nick KICKS < $+ $knick $+ > off $chan
  nkuw
}
;
on *:mode:%embed:{
  echo 4 @embed ###< $+ $nick $+ > Sets $chan to MODE ( $+ $1- $+ )###
}
#embed end
;
;
;
;                           The End
;